#include "tn13def.inc"

; Standard Fuses
; 4 Tasten und Led's an Port B1 bis B4 (Low-Aktiv)
; 1 Piezo Lautsprecher an Port B0

.org 0x000 	rjmp reset				; Reset

.org 0x002 	wdr
		reti					; Pin-Change Interrupt


;==================================================================================================
; Hauptprogramm
;==================================================================================================		

; r19 = Startwert Zufallszahlengenerator
; r20 = aktuelle Zufallszahl 8 bit
; r21 = aktuelle Zufallszahl 2 bit
; r22 = Länge der Melodie
; r23 = Aktueller Ton innerhalb der Melodie (countdown)

; Level 1 = 1-3 Töne
; Level 2 = 4-7 Töne
; Level 3 = 8-15 Töne
; Level 4 = 16-19 Töne
; usw.

reset:		; Das Spiel endet
		rcall watchdog_off		; Watchdog aus schalten
		rcall io_init			; I/O Pins konfigurieren
		rcall takt_38khz		; Taktfrequenz herabsetzen
		rcall ton_falsch		; Erzeuge negativ-ton
		rcall schlafe			; Schlafen

start:		; Das Spiel beginnt
		rcall watchdog_on		; Watchdog an
		rcall random_init		; Zufallszahlen-Generator initialisieren
		ldi r22,2			; Fange mit 2 Tönen an

vorgabe:	rcall pause_800ms

		mov r20,r19			; Beginne Zufallszahlenkette mit dem init-Wert
		mov r23,r22			; Zähle die Töne in r23 (countdown)
vg1:		rcall random			; Erzeuge Zufallszahl
		rcall led_x			; Schalte passende Led an
		rcall ton_x			; Erzeuge passenden Ton
		rcall pause_200ms		; Pause
		rcall led_aus			; Led wieder aus
		rcall pause_200ms		; Pause
		rcall ton_aus			; Ton wieder aus
		dec r23				; Noch ein Ton, falls Countdown>0
		brne vg1

nachspielen:	mov r20,r19			; Beginne Zufallszahlenkette mit dem init-Wert
		mov r23,r22			; Zähle die Töne in r23 (countdown)
ns1:		rcall random			; Erzeuge Zufallszahl
		rcall warte_taste		; Warte auf eine Taste
		cpse r16,r21			; Ist die Taste richtig?
		rjmp reset			; Nein -> Ende 
richtig:	rcall ton_x			; Erzeuge passenden Ton
		rcall pause_200ms		; Pause
		rcall ton_aus			; Ton wieder aus
		rcall warte_keinetaste		; Warte, bis alle Tasten losgelassen
		dec r23				; Noch ein Ton, falls Countdown>0
		brne ns1
				
next_level:	
		rcall pause_200ms
		mov r18,r22			; Länge durch 4 teilen, um den Level zu berechnen
		lsr r18
		lsr r18
		inc r18
nl1:		rcall ton_richtig		; Bestätigungston mehrmals entsprechend dem Level abspielen
		rcall pause_200ms
		dec r18
		brne nl1
		inc r22				; Schwierigkeitsgrad um 1 erhöhen
		rjmp vorgabe


		
;==================================================================================================
; Prozeduren
;==================================================================================================		

io_init:	; I/O Pins konfigurieren
		ldi r16,0b00011110			; Pull-Up an allen Tasten einschalten
		out portb,r16
		sbi ddrb,0				; Lautsprecher-Pin ist ein Ausgang 
		sbi acsr,acd				; Analog Comparator aus schalten		
		ldi r16,(1<<pcie)			; aktiviere Pin-Change Interrupt
		out gimsk,r16	
		ldi r16,0b00011110			; wähle dazu die Pins für die Tasten
		out pcmsk,r16
		sei					; erlaube Interrupts
		ret


watchdog_on:	; Watchdog mit 4 Sekunden Timeout
		wdr					; Setzte den Watchdog Timer zurück
		ldi r16,(1<<wdce)|(1<<wde)|(1<<wdp3)	; Schalte Watchdog ein und Wähle 4s Timeout
		out wdtcr,r16
		ret


watchdog_off:	; Watchdog abschalten
		cli					; Verbiete Unterbrechungen
		wdr					; Setze denWatchdog Timer zurück
		in r16,mcusr				; Lösche das wdrf Flag, lasse die anderen Bits unverändert 
		andi r16,~(1<<wdrf)		
		out mcusr,r16
		in r16,wdtcr				; Setze wdce und wde, lasse die anderen Bits unverändert
		ori r16,(1<<wdce)|(1<<wde)	
		out wdtcr,r16
		andi r16,~(1<<wde)			; Stoppe den Watchdog
		out wdtcr,r16
		sei					; Erlaube Unterbrechungen
		ret


takt_38khz:	; Stelle Taktrate auf 37.5kHz
		ldi r16,(1<<clkpce)			; erlaube Änderung des Clock-Prescaler
		out clkpr,r16
		ldi r16,(1<<clkps3)			; Teile den Takt durch 256
		out clkpr,r16
		ret


schlafe:	; Schlafe ein
		ldi r16,(1<<se)|(1<<sm1)		; Wähle Power-down Modus
		out mcucr,r16
		sleep
		ret


random_init:	; Initialisiere den Zufallszahlen-Generator in r20 und r19
	ri1:	inc r19				; Warte bis irgendeine Taste gedrückt
		in r16,pinb
		com r16
		andi r16,0b00011110
		breq ri1		
	ri2:	inc r19				; Warte bis alle Tasten losgelassen
		in r16,pinb
		com r16
		andi r16,0b00011110
		brne ri2
		tst r19				; Teste, ob r19 gleich Null
		brne ri3			; Erhöhe um eins, wenn gleich Null
		inc r19
	ri3:	mov r20,r19			; Kopiere den Startwert nach r20
		ret


random:		; Erzeuge nächste Zufallszahl in r20 (8bit) und r21 (2bit)
		lsr r20
		brcc rd1
		ori r20,0b10000000
		ldi r16,0b00010110
		eor r20,r16
	rd1:	mov r21,r20
		andi r21,3
		ret


pause_800ms:	; Pause 800ms	
		ldi r16,high(800*37500/3/1000)
		ldi r17,low(800*37500/3/1000)
	p3:	dec r17	
		brne p3
		dec r16
		brne p3
		ret


pause_200ms:	; Pause 200ms	
		ldi r16,high(200*37500/3/1000)
		ldi r17,low(200*37500/3/1000)
	p2:	dec r17	
		brne p2
		dec r16
		brne p2
		ret

pause_50ms:	; Pause 50ms	
		ldi r16,high(50*37500/3/1000)
		ldi r17,low(50*37500/3/1000)
	p1:	dec r17	
		brne p1
		dec r16
		brne p1
		ret


ton_falsch:	; Erzeuge tiefen Ton
		ldi r16,40				; Frequenz festlegen
		out ocr0a,r16
		ldi r16,(1<<wgm01)|(1<<com0a0)		; Timer CTC und Toggle OC0A
		out tccr0a,r16	
		ldi r16,(1<<cs00)			; Verwende Systemtakt ohne Prescaling
		out tccr0b,r16
		rcall pause_800ms			; Pause
		clr r16					; Halte den Timer an = ton aus
		out tccr0b,r16
		ret

ton_richtig:	; Erzeuge Bestätigungs-Ton
		ldi r16,20				; Frequenz festlegen
		out ocr0a,r16
		ldi r16,(1<<wgm01)|(1<<com0a0)		; Timer CTC und Toggle OC0A
		out tccr0a,r16	
		ldi r16,(1<<cs00)			; Verwende Systemtakt ohne Prescaling
		out tccr0b,r16
		rcall pause_50ms			; Pause
		ldi r16,18				; Frequenz festlegen
		out ocr0a,r16
		rcall pause_50ms			; Pause
		ldi r16,16				; Frequenz festlegen
		out ocr0a,r16
		rcall pause_50ms			; Pause
		ldi r16,14				; Frequenz festlegen
		out ocr0a,r16
		rcall pause_50ms			; Pause
		clr r16					; Halte den Timer an = ton aus
		out tccr0b,r16
		ret


ton_x:		; Erzeugt einen Ton, der durch r21 bestimmt wird (0-3)
		ldi r16,20				; Beginne mit 20 (=937Hz)
		sub r16,r21				; Subtrahiere 2x r21, um die Frequenz ggf. zu erhöhen
		sub r16,r21
		out ocr0a,r16				; Timer MAX-Wert festlegen
		ldi r16,(1<<wgm01)|(1<<com0a0)		; Timer CTC und Toggle OC0A
		out tccr0a,r16	
		ldi r16,(1<<cs00)			; Verwende Systemtakt ohne Prescaling
		out tccr0b,r16
		ret

ton_aus:	; Schalte den Ton aus
		clr r16					; Halte den Timer an = ton aus
		out tccr0b,r16
		ret	


led_x:		; Lasse die Led leuchten, deren Nummer durch r21 bestimmt wird (0-3)
		mov r17,r21				; Kopiere r21 nach r17
		ldi r16,2				; Setze in r16 das Bit 1,2,3 oder 4
		tst r17
le2:		breq le1
		lsl r16
		dec r17
		rjmp le2
le1:		com r16					; Led einschalten
		out portb,r16
		com r16
		out ddrb,r16
		ret

led_aus:	; Schalte die Led's aus
		ldi r16,1				; Nur Lautsprecher PIN ist ein Ausgang
		out ddrb,r16
		ldi r16,0b00011110			; Pull-Up an allen Tasten einschalten
		out portb,r16
		ret

warte_taste:	; Schlafe, bis eine Taste gedrückt wurde und liefere die Nummer der Taste in r16 (0-3)
		rcall schlafe
		ldi r16,128	
		sbis pinb,1	
		ldi r16,0
		sbis pinb,2
		ldi r16,1
		sbis pinb,3
		ldi r16,2
		sbis pinb,4
		ldi r16,3
		cpi r16,128
		breq warte_taste
		ret

warte_keinetaste: ; Warte, bis keine Taste mehr gedrückt ist
		in r16,pinb
		com r16
		andi r16,0b00011110
		brne warte_keinetaste
		ret