#include "tn13def.inc"

.org 0x000 	rjmp start				; Reset
.org 0x002 	reti					; Pin-Change Interrupt

start:
		ldi r16,(1<<clkpce)			; erlaube Änderung des Clock-Prescaler
		out clkpr,r16
		ldi r16,(1<<clkps3)			; Teile den Takt durch 256
		out clkpr,r16

		ldi r16,0b00011110			; Pull-Up an allen Tasten einschalten
		out portb,r16

		sbi acsr,acd				; Analog Comparator aus schalteb
		
		ldi r16,(1<<pcie)			; aktiviere Pin-Change Interrupt
		out gimsk,r16	
		ldi r16,0b00011110			; wähle dazu die Pins für die Tasten
		out pcmsk,r16
		sei					; erlaube Interrupts

warte:
		ldi r16,(1<<se)+(1<<sm1)		; Wähle Power-down Modus
		out mcucr,r16
		sleep

taste:
		in r16,pinb				; Tasten abfragen
		com r16					; alle Bits umkehren 0<->1
		andi r16,0b00011110			; nur die Bits von den 4 Tasten herausfiltern
		breq warte				; Nochmal von vorne, wenn keine Taste gedrückt
		cbi portb,1				; Port B1 auf Low = Led1 an
		sbi ddrb,1				; Port B1 ist Ausgang

pause:	
		clr r16					; Warteschleife, die 65536 mal durchlaufen wird
		clr r17					; ergibt etwa 5 Sekunden
	p1:	dec r17	
		brne p1
		dec r16
		brne p1

led_aus:	
		cbi ddrb,1				; Port B1 ist wieder ein Eingang
		sbi portb,1				; Pullup von Port B1 einschalten

		rjmp warte