#include "tn13def.inc"

.org 0x000 	rjmp start				; Reset
.org 0x002 	reti					; Pin-Change Interrupt


;==================================================================================================
; Hauptprogramm
;==================================================================================================		

start:
		rcall init				; Initialisiere den Mikrocontroller
		rcall takt_38khz			; Taktfrequenz herabsetzen

warte:
		rcall schlafe				; Schlafe ein

		in r16,pinb				; Tasten abfragen
		com r16					; alle Bits umkehren 0<->1
		andi r16,0b00011110			; nur die Bits von den 4 Tasten herausfiltern
		breq warte				; Nochmal von vorne, wenn keine Taste gedrückt

		rcall led_blinken			; Led 1x blinken 
		rcall warte



;==================================================================================================
; Prozeduren
;==================================================================================================		

init:		; Initialisiere den Mikrocontroller
		sbi acsr,acd				; Analog Comparator aus schalten
		ldi r16,0b00011110			; Pull-Up an allen Tasten einschalten
		out portb,r16
		ldi r16,(1<<pcie)			; aktiviere Pin-Change Interrupt
		out gimsk,r16	
		ldi r16,0b00011110			; wähle dazu die Pins für die Tasten
		out pcmsk,r16
		sei					; erlaube Interrupts
		ret


takt_38khz:	; Stelle Taktrate auf 37.5kHz
		ldi r16,(1<<clkpce)			; erlaube Änderung des Clock-Prescaler
		out clkpr,r16
		ldi r16,(1<<clkps3)			; Teile den Takt durch 256
		out clkpr,r16
		ret


schlafe:	; Schlafe ein
		ldi r16,(1<<se)+(1<<sm1)		; Wähle Power-down Modus
		out mcucr,r16
		sleep
		ret


pause_1s:	; Pause 1 Sekunde	
		ldi r16,high(1*37500/3)
		ldi r17,low(1*37500/3)
	p1:	dec r17	
		brne p1
		dec r16
		brne p1
		ret


led_blinken:	; Led1 einmal blinken
		cbi portb,1				; Port B1 auf Low = Led1 an
		sbi ddrb,1				; Port B1 ist Ausgang
		rcall pause_1s				; Pause 1s
		cbi ddrb,1				; Port B1 ist wieder ein Eingang
		sbi portb,1				; Pullup von Port B1 einschalten
		rcall pause_1s				; Pause 1s
		ret