#include "tn13def.inc"

.org 0x000 	rjmp reset				; Reset

.org 0x002 	wdr					; Pin-Change Interrupt
		reti


;==================================================================================================
; Reset
;==================================================================================================		

reset:
		rcall init				; Initialisiere den Mikrocontroller
		rcall takt_38khz			; Taktfrequenz herabsetzen
		rcall watchdog_off			; Watchdog aus
		rcall schlafe				; Schlafe ein
		rjmp start


;==================================================================================================
; Hauptprogramm
;==================================================================================================		

start:
		rcall watchdog_on			; Watchdog an
		rjmp t11				; Überspringe den nächsten Schlaf beim ersten Durchlauf

nochmal:

	t1:	rcall schlafe				; Warte auf Taste 1
	t11:	sbic pinb,1				
		rjmp t1
		rcall ton_1600hz

	t2:	rcall schlafe				; Warte auf Taste 2
		sbic pinb,2				
		rjmp t2
		rcall ton_1600hz

	t3:	rcall schlafe				; Warte auf Taste 3
		sbic pinb,3				
		rjmp t3
		rcall ton_1600hz

	t4:	rcall schlafe				; Warte auf Taste 4
		sbic pinb,4				
		rjmp t4
		rcall ton_3200hz

		rjmp nochmal


;==================================================================================================
; Prozeduren
;==================================================================================================		

init:		; Initialisiere den Mikrocontroller
		sbi acsr,acd				; Analog Comparator aus schalten
		sbi ddrb,0				; Lautsprecher-Pin ist ein Ausgang 
		ldi r16,0b00011110			; Pull-Up an allen Tasten einschalten
		out portb,r16
		ldi r16,(1<<pcie)			; aktiviere Pin-Change Interrupt
		out gimsk,r16	
		ldi r16,0b00011110			; wähle dazu die Pins für die Tasten
		out pcmsk,r16
		sei					; erlaube Interrupts
		ret


takt_38khz:	; Stelle Taktrate auf 37.5kHz
		ldi r16,(1<<clkpce)			; erlaube Änderung des Clock-Prescaler
		out clkpr,r16
		ldi r16,(1<<clkps3)			; Teile den Takt durch 256
		out clkpr,r16
		ret


schlafe:	; Schlafe ein
		ldi r16,(1<<se)+(1<<sm1)		; Wähle Power-down Modus
		out mcucr,r16
		sleep
		ret


pause_500ms:	; Pause 500ms	
		ldi r16,high(500*37500/3/1000)
		ldi r17,low(500*37500/3/1000)
	p1:	dec r17	
		brne p1
		dec r16
		brne p1
		ret


ton_1600hz:	; Erzeuge Ton mit 1600hz
		ldi r16,(37500/2/1600)			; Frequenz festlegen
		out ocr0a,r16
		ldi r16,(1<<wgm01)+(1<<com0a0)		; Timer CTC und Toggle OC0A
		out tccr0a,r16	
		ldi r16,(1<<cs00)			; Verwende Systemtakt ohne Prescaling
		out tccr0b,r16
		rcall pause_500ms			; Pause
		clr r16					; Halte den Timer an = ton aus
		out tccr0b,r16
		rcall pause_500ms			; Pause
		ret


ton_3200hz:	; Erzeuge Ton mit 3200hz
		ldi r16,(37500/2/3200)			; Frequenz festlegen
		out ocr0a,r16
		ldi r16,(1<<wgm01)+(1<<com0a0)		; Timer CTC und Toggle OC0A
		out tccr0a,r16	
		ldi r16,(1<<cs00)			; Verwende Systemtakt ohne Prescaling
		out tccr0b,r16
		rcall pause_500ms			; Pause
		clr r16					; Halte den Timer an = ton aus
		out tccr0b,r16
		rcall pause_500ms			; Pause
		ret


watchdog_on:	; Watchdog mit 4 Sekunden Timeout
		wdr					; Setzte den Watchdog Timer zurück
		ldi r16,(1<<wdce)+(1<<wde)+(1<<wdp3)	; Schalte Watchdog ein und Wähle 4s Timeout
		out wdtcr,r16
		ret


watchdog_off:	; Watchdog abschalten
		cli					; Verbiete Unterbrechungen
		wdr					; Setze denWatchdog Timer zurück
		in r16,mcusr				; Lösche das wdrf Flag, lasse die anderen Bits unverändert 
		andi r16,~(1<<wdrf)		
		out mcusr,r16
		in r16,wdtcr				; Setze wdce und wde, lasse die anderen Bits unverändert
		ori r16,(1<<wdce)|(1<<wde)	
		out wdtcr,r16
		andi r16,~(1<<wde)			; Stoppe den Watchdog
		out wdtcr,r16
		sei					; Erlaube Unterbrechungen
		ret